所以吟清最近对生成html比较感兴趣,看了不少文章,也有一点点收获.
1,下面这个例子直接利用FSO把html代码写入到文件中然后生成.html格式的文件-->
<%
Randomize() '生成随机数
fname=Int((1000000-1+1)*Rnd(now())+1)'把随机数赋值给变量fname
filename="CreateObject/"&fname&".htm" '生成的文件名
if request("body")<>"" then
set fso = Server.CreateObject("Scripting.FileSystemObject")'定义FSO对象
set fout = fso.CreateTextFile(server.mappath(""&filename&""))'定义创建对象
fout.write "标题(title):" & request.form("title") & "<br>" '要写的内容
fout.write "内容(body):" & request.form("body") '要写的内容
fout.close '关闭
set fout=nothing '清空
set fso=nothing '清空
end if
%>
<form name="form1" method="post" action="">
<input name="title" size=18><br>
<textarea name="body"></textarea>
<br>
<br>
<input type="submit" name="Submit" value="生成">
</form>
<!--2,但是按照上面的方法生成html文件非常不方便,第二种方法就是利用模板技术,将模板中特殊代码的值替换为从表单或是数据库字段中接受过来的值,完成模板功能;将最终替换过的所有模板代码生成HTML文件.这种技术采用得比较多,大部分的CMS都是使用这类方法.-->
<%
Dim fso,htmlwrite
Dim strTitle,strContent,strOut
'创建文件系统对象
Set fso=Server.CreateObject("Scripting.FileSystemObject")
'打开网页模板文件，读取模板内容
Set htmlwrite=fso.OpenTextFile(Server.MapPath("Templets/Templets.htm"))
'读取模板内容
strOut=htmlwrite.ReadAll
htmlwrite.close '关闭
strTitle="生成的网页标题" '要写的内容
strC '要写的内容
'用真实内容替换模板中的标记
strOut=Replace(strOut,"$title$",strTitle)
strOut=Replace(strOut,"$body$",strContent)
'创建要生成的静态页
Randomize() '生成随机数
fname=Int((1000000-1+1)*Rnd(now())+1) '赋值给变量
filename="CreateObject/"&fname&".htm" '生成的文件名
Set htmlwrite=fso.CreateTextFile(server.mappath(""&filename&""),true) '定义创建对象
'写入网页内容
htmlwrite.WriteLine strOut
htmlwrite.close
Response.Write "生成静态页成功！"
'释放文件系统对象
set htmlwrite=Nothing
set fso=Nothing
%>
<!--3,第三种方法就是用XMLHTTP获取动态页生成的HTML内容，再用ADODB.Stream或者Scripting.FileSystemObject保存成html文件。这句话是在蓝色理想上看到的,对XMLHTTP吟清还不熟悉正在找资料了解.找到一段XMLHTTP生成Html的代码参考一下.-->
<%
'常用函数
'1、输入url目标网页地址，返回值getHTTPPage是目标网页的html代码
function getHTTPPage(url)
dim Http
set Http=server.createobject("MSXML2.XMLHTTP")
Http.open "GET",url,false
Http.send()
if Http.readystate<>4 then
exit function
end if
getHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
set http=nothing
if err.number<>0 then err.Clear
end function
'2、转换乱玛，直接用xmlhttp调用有中文字符的网页得到的将是乱玛，可以通过adodb.stream组件进行转换
Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
set objstream = nothing
End Function
txtURL=server.MapPath("Templets/Templets.htm")
sText = getHTTPPage(txtURL)
Set FileObject=Server.CreateObject("Scripting.FileSystemObject")
filename="CreateObject/index.htm"
Set openFile=FileObject.OpenTextfile(server.mapPath(filename),2,true) 'true为不存在自行建立
openFile.writeline(sText)
Set OpenFile=nothing
%>
<script>
alert("静态网页生成完毕");
history.back();
</script>
最新评论